530 lines
14 KiB
VimL
530 lines
14 KiB
VimL
" ●
|
||
|
||
" #functions {{{
|
||
|
||
function! MyFoldText() "{{{
|
||
if !exists('g:foldtext_column')
|
||
let g:foldtext_column = 80 " column to right align foldtext with
|
||
endif
|
||
|
||
if !exists('b:foldtext_column')
|
||
let b:foldtext_column = g:foldtext_column " column to right align foldtext with
|
||
endif
|
||
|
||
if !exists('g:foldtext_maxcolumn')
|
||
let g:foldtext_maxcolumn = 120
|
||
endif
|
||
|
||
let l:linecount = v:foldend - v:foldstart
|
||
" don't display foldmarker braces
|
||
" put one of the braces in brackets so vim doesn't treat
|
||
" it as an actual fold marker
|
||
let l:line = substitute(getline(v:foldstart), '"\?{\({\){', '', '')
|
||
" don't display vim comment quotation marks
|
||
" TODO other comment markers
|
||
let l:line = substitute(l:line, "\^\"\\s\\?", '', '')
|
||
|
||
" let l:postfix = l:linecount . ' ' . substitute(v:folddashes, '-', '•', 'g')
|
||
let l:postfix = l:linecount . ' ' . substitute(v:folddashes, '-', '↓', 'g')
|
||
while strchars(l:postfix) < 7
|
||
let l:postfix = ' ' . l:postfix
|
||
endwhile
|
||
" let l:postfix = ' ↓ ' . l:postfix
|
||
|
||
let l:len_line = len(l:line)
|
||
let l:len_postfix = strchars(l:postfix)
|
||
|
||
if l:len_line + l:len_postfix <= b:foldtext_column
|
||
let l:padding = ' '[l:len_line + l:len_postfix + 0:b:foldtext_column - 1]
|
||
let l:foldtext = l:line . l:padding . l:postfix
|
||
else
|
||
let l:sniptext = ' ⋯'
|
||
let l:foldtext = l:line[:b:foldtext_column - 1 - strchars(l:sniptext) - l:len_postfix] . l:sniptext . l:postfix
|
||
endif
|
||
|
||
return l:foldtext
|
||
endfunction
|
||
|
||
"}}}
|
||
function! <SID>SynStack()"{{{
|
||
if !exists('*synstack')
|
||
return
|
||
endif
|
||
echo map(synstack(line('.'), col('.')), 'synIDattr(v:val,"name")') '-> ' . synIDattr(synIDtrans(synID(line('.'),col('.'),1)), 'name' )
|
||
endfunc
|
||
nmap <space>pp :call <SID>SynStack()<CR>
|
||
"}}}
|
||
|
||
function! s:RunShellCommand(cmdline) abort"{{{
|
||
" Shell command
|
||
" http://vim.wikia.com/wiki/VimTip1599
|
||
|
||
let l:expanded_cmdline = a:cmdline
|
||
for l:part in split(a:cmdline, ' ')
|
||
if l:part[0] =~ '\v[%#<]'
|
||
let l:expanded_part = fnameescape(expand(l:part))
|
||
let l:expanded_cmdline = substitute(l:expanded_cmdline, l:part, l:expanded_part, '')
|
||
endif
|
||
endfor
|
||
|
||
if g:shell_scratch_buffer_nr > -1
|
||
let l:win_nr = bufwinnr(g:shell_scratch_buffer_nr)
|
||
if l:win_nr < 0
|
||
execute 'bdelete' g:shell_scratch_buffer_nr
|
||
top new
|
||
let g:shell_scratch_buffer_nr = bufnr('%')
|
||
else
|
||
execute l:win_nr. ' wincmd w'
|
||
setlocal modifiable
|
||
%delete _
|
||
endif
|
||
else
|
||
top new
|
||
let g:shell_scratch_buffer_nr = bufnr('%')
|
||
endif
|
||
|
||
setlocal buftype=nofile bufhidden=wipe nobuflisted noswapfile nowrap
|
||
nnoremap <buffer> q :bdelete<CR>
|
||
augroup ResetShellBufferNr
|
||
autocmd! * <buffer>
|
||
autocmd BufUnload <buffer> let g:shell_scratch_buffer_nr = -1
|
||
augroup END
|
||
|
||
" call setline(1, 'You entered: ' . a:cmdline)
|
||
" call setline(2, 'Expanded Form: ' .l:expanded_cmdline)
|
||
" call setline(3,substitute(getline(2),'.','=','g'))
|
||
execute '$read !'. l:expanded_cmdline
|
||
1
|
||
|
||
setlocal nomodifiable
|
||
if !exists('b:shell_line_count')
|
||
let b:shell_line_count = line('$')
|
||
if b:shell_line_count > 25
|
||
let b:shell_line_count = 20
|
||
endif
|
||
execute 'resize' b:shell_line_count + 1
|
||
endif
|
||
|
||
wincmd p
|
||
endfunction
|
||
|
||
command! -complete=shellcmd -nargs=+ Shell call s:RunShellCommand(<q-args>)
|
||
let g:shell_scratch_buffer_nr = -1
|
||
|
||
"}}}
|
||
function! SaveAndExecute(ex_command) abort "{{{
|
||
" https://stackoverflow.com/a/40195855
|
||
" ex_command: command to run to execute file
|
||
" SOURCE [reusable window]: https://github.com/fatih/vim-go/blob/master/autoload/go/ui.vim
|
||
|
||
" save and reload current file
|
||
silent execute 'update | edit'
|
||
|
||
" get file path of current file
|
||
let s:current_buffer_file_path = expand('%')
|
||
|
||
let s:output_buffer_name = 'Output'
|
||
let s:output_buffer_filetype = 'output'
|
||
|
||
" reuse existing buffer window if it exists otherwise create a new one
|
||
if !exists('c:buf_nr') || !bufexists(s:buf_nr) || bufwinnr(s:buf_nr) == -1
|
||
silent execute 'top new ' . s:output_buffer_name
|
||
let s:buf_nr = bufnr('%')
|
||
elseif bufwinnr(s:buf_nr) != bufwinnr('%')
|
||
silent execute bufwinnr(s:buf_nr) . 'wincmd w'
|
||
endif
|
||
|
||
silent execute 'setlocal filetype=' . s:output_buffer_filetype
|
||
setlocal bufhidden=delete
|
||
setlocal buftype=nofile
|
||
setlocal noswapfile
|
||
setlocal nobuflisted
|
||
setlocal winfixheight
|
||
setlocal cursorline " make it easy to distinguish
|
||
" setlocal nonumber
|
||
" setlocal norelativenumber
|
||
setlocal showbreak=""
|
||
|
||
nnoremap <silent> <buffer> q :bdelete!<CR>'.zz
|
||
|
||
" clear the buffer
|
||
setlocal noreadonly
|
||
" setlocal modifiable
|
||
%delete _
|
||
|
||
" add the console output
|
||
silent execute '.!'. a:ex_command . ' ' . shellescape(s:current_buffer_file_path, 1)
|
||
|
||
" resize window to content length
|
||
" Note: This is annoying because if you print a lot of lines then your code buffer is forced to a height of one line every time you run this function.
|
||
" However without this line the buffer starts off as a default size and if you resize the buffer then it keeps that custom size after repeated runs of this function.
|
||
" But if you close the output buffer then it returns to using the default size when its recreated
|
||
"execute 'resize' . line('$')
|
||
|
||
" make the buffer non modifiable
|
||
setlocal readonly
|
||
" setlocal nomodifiable
|
||
endfunction
|
||
|
||
"}}}
|
||
function! JsIncludeExpr(file)"{{{
|
||
" substitute(substitute(v:fname,'^[\\~@]\/','./',''),'^[\\~@]','./node_modules/','')
|
||
return substitute(substitute(a:file,'^[\\~@]\/','./',''),'^[\\~@]','./node_modules/','')
|
||
|
||
endfunction
|
||
|
||
"}}}
|
||
function! Redir(cmd) "{{{
|
||
for win in range(1, winnr('$'))
|
||
if getwinvar(win, 'scratch')
|
||
execute win . 'windo close'
|
||
endif
|
||
endfor
|
||
if a:cmd =~ '^!'
|
||
let output = system(matchstr(a:cmd, '^!\zs.*'))
|
||
else
|
||
redir => output
|
||
execute a:cmd
|
||
redir END
|
||
endif
|
||
vnew
|
||
let w:scratch = 1
|
||
setlocal buftype=nofile bufhidden=wipe nobuflisted noswapfile
|
||
call setline(1, split(output, "\n"))
|
||
endfunction
|
||
|
||
command! -nargs=1 -complete=command Redir silent call Redir(<q-args>)
|
||
" Usage:
|
||
" :Redir hi ............. show the full output of command ':hi' in a scratch window
|
||
" :Redir !ls -al ........ show the full output of command ':!ls -al' in a scratch window
|
||
"}}}
|
||
"----------------------------------------------------------------------------}}}
|
||
"#commands{{{
|
||
" TrimWhitespace{{{
|
||
command! -range=% TrimWhitespace let b:wv = winsaveview() |
|
||
\ keeppattern <line1>,<line2>s/\s\+$// |
|
||
\ call winrestview(b:wv)
|
||
"}}}
|
||
" Scratch, ScratchVertical{{{
|
||
command! Scratch new | setlocal buftype=nofile | setlocal bufhidden=hide | setlocal noswapfile
|
||
command! ScratchVertical vnew | setlocal buftype=nofile | setlocal bufhidden=hide | setlocal noswapfile
|
||
"}}}
|
||
"}}}
|
||
" #settings {{{
|
||
|
||
scriptencoding utf-8
|
||
set ttyfast
|
||
|
||
set dictionary+=/usr/share/dict/brit-a-z.txt,/usr/share/dict/britcaps.txt
|
||
set thesaurus+=/usr/share/dict/mthesaur.txt
|
||
|
||
" disable background color erase
|
||
" https://sunaku.github.io/vim-256color-bce.html
|
||
set t_ut=
|
||
|
||
syntax on
|
||
set fillchars=stl:\ ,stlnc:\ ,vert:\|,fold:\
|
||
|
||
set guioptions-=mTrLb
|
||
set guioptions+=c
|
||
|
||
if exists('+termguicolors')
|
||
let &t_8f = "\<Esc>[38;2;%lu;%lu;%lum"
|
||
let &t_8b = "\<Esc>[48;2;%lu;%lu;%lum"
|
||
set termguicolors
|
||
endif
|
||
|
||
colorscheme monotonous-dark
|
||
|
||
set updatetime=100
|
||
set timeoutlen=500
|
||
set lazyredraw
|
||
|
||
" the ;/home/ray tells vim to stop searching at /home/ray
|
||
set tags+=./.tags,.tags,./tags-py,.tags-py;/home/ray/
|
||
|
||
" persisitent undo file
|
||
set undofile
|
||
set undodir=~/.vim/.vimtmp
|
||
set backupdir=~/.vim/.vimtmp
|
||
set directory=~/.vim/.vimtmp
|
||
|
||
set viewoptions-=options
|
||
|
||
set ignorecase
|
||
set smartcase
|
||
|
||
set wildmenu
|
||
set wildmode=longest:full,full
|
||
set wildignore+=/node_modules/,dist/
|
||
|
||
" Use ag over grep
|
||
if executable('ag')
|
||
set grepprg=ag\ --nogroup\ --nocolor\ --ignore\ node_modules
|
||
endif
|
||
|
||
set hidden
|
||
|
||
set hlsearch
|
||
|
||
set completeopt=menuone
|
||
|
||
set nospell
|
||
set spelllang=en_gb
|
||
|
||
set diffopt+=vertical
|
||
|
||
set rnu nu
|
||
|
||
set tabstop=8
|
||
set softtabstop=2
|
||
set shiftwidth=2
|
||
set shiftround
|
||
set expandtab
|
||
set autoindent
|
||
|
||
set textwidth=120
|
||
set formatoptions=cq
|
||
set wrapmargin=0
|
||
|
||
set cursorline
|
||
|
||
set foldcolumn=2
|
||
if has('patch-7-4-2201')
|
||
set signcolumn=yes
|
||
endif
|
||
set colorcolumn=80,120
|
||
|
||
set iskeyword+=-
|
||
set scrolloff=10
|
||
set showcmd
|
||
set incsearch
|
||
|
||
set laststatus=2
|
||
set shortmess=aoOT
|
||
set cmdheight=3
|
||
|
||
set foldmethod=indent
|
||
set foldnestmax=3
|
||
set foldlevelstart=2
|
||
|
||
set showmode
|
||
|
||
set autoindent
|
||
set breakindent
|
||
set showbreak=\ \ ↳\
|
||
|
||
set mouse=a
|
||
|
||
set listchars=eol:¬,tab:>-,trail:~,extends:>,precedes:<,space:·
|
||
|
||
set foldtext=MyFoldText()
|
||
set conceallevel=0
|
||
"----------------------------------------------------------------------------}}}
|
||
" #mappings {{{
|
||
let g:mapleader = ' '
|
||
" search and replace {{{
|
||
nnoremap <space>rr :%s/\<<C-r>=expand('<cword>')<CR>\>//g<left><left>
|
||
"}}}
|
||
" #syntax
|
||
nnoremap <silent> <cr>s :syntax on<cr>
|
||
nnoremap <silent> <cr>S :syntax off<cr>
|
||
" miscallaneous {{{
|
||
nnoremap <cr>l :colorscheme monotonous-light<cr>
|
||
nnoremap <cr>d :colorscheme monotonous-dark<cr>
|
||
nnoremap 0 ^
|
||
nnoremap <silent><space>cs :let @/=""<cr>
|
||
nnoremap <space>: :setlocal number<CR>:
|
||
nnoremap <silent> <space>rc :so $MYVIMRC<CR>
|
||
nnoremap <silent><expr> <space>nh (&hls && v:hlsearch ? ':nohls' : ':set hls')."\n"
|
||
nnoremap <silent> <space>sl :set invlist<CR>
|
||
nnoremap <space>aa A<left>
|
||
nnoremap <space>a2 A<left><left>
|
||
nnoremap <space>ab A<C-o>B
|
||
nnoremap <space>co :!clear;
|
||
nnoremap <space>;; A;<esc>
|
||
nnoremap <space>;j jA;<esc>
|
||
nnoremap <space>,, A,<esc>
|
||
nnoremap <space>,j jA,<esc>
|
||
" Focus on current fold, close the rest
|
||
nnoremap <silent> <space>zz zMzvzt
|
||
" replace current word with last yanked/deleted text
|
||
nnoremap <silent> <space>rw "_diwP
|
||
" replace current word with last yanked text
|
||
nnoremap <silent> <space>ry diw"0P
|
||
" quick grep of visual selection
|
||
vnoremap <space>gr y:grep! -R <C-r>" .
|
||
" open quickfix window of TODOs
|
||
" FIXME i want fixme!!!
|
||
nnoremap <space>td :grep -RE '(TODO\\|FIXME)' .<CR>:botright cwindow<CR>:echo len(getqflist()) 'TODOs'<CR>
|
||
" devdocs mapping
|
||
nnoremap <space>dd :DD<CR>
|
||
" write and delete current buffer
|
||
nnoremap <space>bx :w\|bd<cr>
|
||
" sync highlighting from start
|
||
nnoremap <silent><space>ss :syntax sync fromstart<CR>
|
||
|
||
"}}}
|
||
" terminal{{{
|
||
if has('terminal')
|
||
tnoremap <Esc> <C-\><C-n>
|
||
endif
|
||
"}}}
|
||
" windows{{{
|
||
nnoremap <space>ww :resize<CR>:vertical resize<CR>
|
||
|
||
" }}}
|
||
" git mappings {{{
|
||
" also see vim-fugitive plugin section
|
||
nnoremap <space>gD :!clear; echo 'git diff'; git diff<CR>
|
||
nnoremap <space>ga :!clear; git add %; git status<CR>
|
||
nnoremap <space>gA :!clear; git add .; git status<CR>
|
||
nnoremap <space>gg :!clear; git add %; git commit -m ''<Left>
|
||
nnoremap <space>gP :!clear; echo 'git push'; git push<CR>
|
||
|
||
"}}}
|
||
" movement/navigation{{{
|
||
nnoremap <Esc>j :resize -5<CR>
|
||
nnoremap <Esc>k :resize +5<CR>
|
||
nnoremap <Esc>l :vertical resize +5<CR>
|
||
nnoremap <Esc>h :vertical resize -5<CR>
|
||
" alias for :tjump <cword>
|
||
nnoremap <space>tj g<C-]>
|
||
" alias for :ptjump <cword>
|
||
nnoremap <space>tp <C-w>g}
|
||
|
||
"}}}
|
||
" location list and quickfix mappings {{{
|
||
nnoremap <space>lo :botright lwindow<CR>
|
||
nnoremap <up> :lprev<CR>zv
|
||
nnoremap <down> :lnext<CR>zv
|
||
nnoremap <space>lc :lclose<CR>
|
||
nnoremap <space>lh :lhistory<CR>
|
||
nnoremap <space>lp :lolder<CR>
|
||
nnoremap <space>ln :lnewer<CR>
|
||
|
||
nnoremap <space>qo :botright cwindow<CR>
|
||
nnoremap <left> :cprev<CR>zv
|
||
nnoremap <right> :cnext<CR>zv
|
||
nnoremap <space>qc :cclose<CR>
|
||
nnoremap <space>qh :chistory<CR>
|
||
nnoremap <space>qp :colder<CR>
|
||
nnoremap <space>qn :cnewer<CR>
|
||
|
||
"}}}
|
||
" insert mode mappings {{{
|
||
inoremap jkrg <c-o>:reg<cr>
|
||
inoremap :w<cr> :w<cr>
|
||
inoremap [:w<cr> :w<cr>
|
||
inoremap {:w<cr> :w<cr>
|
||
" Chain multiple path completions with / key. Selects the first suggestion if
|
||
" no current selection. Use ctrl-y to finish completion as normal.
|
||
inoremap <expr> / pumvisible()
|
||
\ ? len(v:completed_item) ? '<C-Y><C-X><C-F>' : '<C-N><C-Y><C-X><C-F>'
|
||
\ : '/'
|
||
|
||
"}}}
|
||
" working_with_underscores{{{
|
||
nnoremap <space>w f_l
|
||
nnoremap <space>b hT_
|
||
nnoremap <space>e lt_
|
||
onoremap u t_
|
||
onoremap U f_
|
||
"}}}
|
||
"----------------------------------------------------------------------------}}}
|
||
" #abbreviations {{{
|
||
|
||
" spelling"{{{
|
||
iabbrev adn and
|
||
iabbrev waht what
|
||
iabbrev tehn then
|
||
iabbrev functin function
|
||
iabbrev positin position
|
||
|
||
"}}}
|
||
" css{{{
|
||
iabbrev pabs; position: absolute;
|
||
iabbrev pfix; position: fixed;
|
||
iabbrev prel; position: relative;
|
||
iabbrev fdr; flex-direction: row;
|
||
iabbrev fdc; flex-direction: column;
|
||
iabbrev jcc; justify-content: center;
|
||
iabbrev aic; align-items: center;
|
||
iabbrev t0; top: 0;
|
||
iabbrev b0; bottom: 0;
|
||
iabbrev l0; left: 0;
|
||
iabbrev r0; right: 0;
|
||
|
||
iabbrev ct'' content-type: '';
|
||
|
||
"}}}
|
||
|
||
"----------------------------------------------------------------------------}}}
|
||
" #autocommands {{{
|
||
|
||
" persistent folds {{{
|
||
augroup AutoSaveFolds
|
||
autocmd!
|
||
autocmd BufWrite ?* mkview
|
||
autocmd BufRead ?* silent! loadview
|
||
augroup END
|
||
|
||
" }}}
|
||
" Show trailing whitepace and spaces before a tab: {{{
|
||
augroup whitespaceerrors
|
||
autocmd!
|
||
autocmd Syntax * syn match ExtraWhitespace /\s\+$\| \+\ze\t/ containedin=ALL
|
||
augroup END
|
||
|
||
" }}}
|
||
" automatically reload if color scheme file written {{{
|
||
" augroup coloreload
|
||
" autocmd!
|
||
" autocmd BufWritePost customred256.vim so $MYVIMRC
|
||
" augroup end
|
||
"
|
||
|
||
" }}}
|
||
" line numbering {{{
|
||
" if exists('##CmdlineEnter')
|
||
" augroup linenumbering
|
||
" autocmd!
|
||
" autocmd CmdlineEnter * :redraw | :set number
|
||
" autocmd CmdlineLeave * :set nonumber
|
||
" augroup END
|
||
" endif
|
||
|
||
" }}}
|
||
" Automatically reload .vimrc if changed {{{
|
||
augroup myvimrc
|
||
autocmd!
|
||
autocmd BufWritePost .vimrc,_vimrc,vimrc,.gvimrc,_gvimrc,gvimrc so $MYVIMRC | if has('gui_running') | so $MYGVIMRC | endif
|
||
augroup END
|
||
|
||
" }}}
|
||
" Open quickfix window{{{
|
||
augroup QuickFixAutoload
|
||
autocmd!
|
||
autocmd QuickFixCmdPost [^l]* nested botright cwindow
|
||
autocmd QuickFixCmdPost l* nested botright lwindow
|
||
augroup END
|
||
|
||
" }}}
|
||
|
||
"----------------------------------------------------------------------------}}}
|
||
" #statusline {{{
|
||
set statusline=\
|
||
set statusline+=[%n]\ \
|
||
set statusline+=%l\ of\ %L\
|
||
set statusline+=(%p%%)
|
||
set statusline+=%=
|
||
set statusline+=%y\
|
||
set statusline+=%r\ %m\ %F
|
||
set statusline+=\
|
||
|
||
"----------------------------------------------------------------------------}}}
|
||
|
||
|
||
|
||
" vim: set foldmethod=marker:
|